Der Begriff der Kohärenzlänge kann mit Wellenpaketen veranschaulicht werden.
| > | restart: with(plots): |
Als Einhüllende nimmt man ein Gaußpaket mit Zentrum bei x0
| > | N:=(x,x0,s)->exp(-(x-x0)^2/(2*s^2))/sqrt(2*Pi*s^2); |
 |
(1) |
und multipliziert es mit einer Cosinus-Welle
| > | yon:=(x,x0,s,lambda)->N(x,x0,s)*cos(2*Pi/lambda*(x-x0)); |
![Typesetting:-mprintslash([yon := proc (x, x0, s, lambda) options operator, arrow; `*`(N(x, x0, s), `*`(cos(`+`(`/`(`*`(2, `*`(Pi, `*`(`+`(x, `-`(x0))))), `*`(lambda)))))) end proc], [proc (x, x0, s, l...](images/kh_htm_pub_2.gif){kind=small} |
(2) |
| > | yon(x,x0,s,lambda); |
 |
(3) |
Normierungsfaktor für die Gesamtintensität (Amplitudenquadrat) = 1
| > | NN:=int(yon(x,x0,s,lambda)^2,x=-infinity..infinity) assuming s::real, s>0; |
 |
(4) |
| > | NN:=unapply(NN,s,lambda); |
 |
(5) |
Normiertes Wellenpaket
| > | y:=(x,x0,s,lambda)->N(x,x0,s)/sqrt(NN(s,lambda))*cos(2*Pi/lambda*(x-x0)); |
 |
(6) |
| > | y(x,x0,s,lambda); |
 |
(7) |
Das Wellenpaket sieht nun so aus
| > | plot(y(x,0,2,1),x=-10..10); |
 |
Das Wellenpaket soll mit einem zweiten interferieren, wobei der Gangunterschied der Pakete unterschiedliche Werte annehmen kann. Also verschieben wir das Paket in Gedanken einmal nach rechts
| > | p1:=animate( plot, [y(x,x0,2,1), x=-10..10, thickness=2], x0=0..5,frames=50 ): |
| > | p1; |
 |
und einmal nach links
| > | p2:=animate( plot, [y(x,-x0,2,1), x=-10..10, thickness=2], x0=0..5,frames=50 ): |
| > | p2; |
 |
"Am Ort des Schirms" (x=0) kommen die Pakete also so an, wenn man den Gangunterschied (2*x0) ändert:
| > | display(p1,p2); |
 |
Addiert man die Amplituden, so ergibt sich folgendes Bild (etwas nach oben verschoben zur Unterscheidung von den Summanden, s.u.)
| > | p3:=animate( plot, [y(x,x0,2,1)+y(x,-x0,2,1)+.05, x=-10..10, thickness=2,color=blue], x0=0..5 ,frames=50): |
| > | p3; |
 |
Oder zusammen mit den Paketen (Summanden) dargestellt
| > | display(p1,p2,p3); |
 |
Detektoren (oder Schirme) registrieren Intensität, also müssen wir die Summe der Amplituden (blaue Kurve von oben) zunächst quadrieren.
| > | p4:=animate( plot, [(y(x,x0,2,1)+y(x,-x0,2,1))^2, x=-5..5, thickness=2], x0=0..3,frames = 100 ): |
| > | p4; |
 |
Und dann noch die insgesamt absorbierte Intensität "am Ort des Schirms" (oder Interferenzpunktes) berechnen:
Die ortsabhängige Intensität war
| > | intens:=(y(x,x0,s,lambda)/sqrt(2)+y(x,-x0,s,lambda)/sqrt(2))^2; |
 |
(8) |
und muss über x integriert werden
| > | Intens:=int(intens,x=-infinity..infinity) assuming s>0; |
   |
(9) |
| > | evalc(Intens); |
      |
(10) |
Was sich vereinfachen lässt zu
| > | Intens:=combine(%); |
 |
(11) |
Das bedeutet für die Fälle s≫λ (große Kohärenzlänge) und s≪λ (kleine Kohärenzlänge):
| > | Intensa:=subs(s=a*lambda,Intens); |
 |
(12) |
s≫λ
| > | limit(%,a=infinity); |
 |
(13) |
| > | combine(%); |
 |
(14) |
Also das bekannte (idealisierte) Interferenzmuster mit voller Sichtbarkeit.
Und für s≪λ
| > | limit(Intensa,a=0) assuming x0::real,lambda::real; |
 |
(15) |
also konstante Intensität und kein Interferenzmuster (der andere "Idealfall").
Und für s = λ (als Beispiel)
| > | s:=2: lambda:=2: |
| > | plot(Intens,x0=-5..5,0..2); |
 |
Die zugehörige Gleichung sieht so aus
| > | simplify(Intens); |
 |
(16) |
Oder als "Interferenzstreifen"
| > | plot3d(Intens,x0=-4..4,y=0..1,shading=zgreyscale,style=patchnogrid,lightmodel=none,orientation=[-90,0,0],grid=[100,10],tickmarks=[10,0,0],labels=[x0," "," "]); |
 |
Um Missverständnissen (nachträglich) vorzubeugen: Obige Interferenzstreifen entstehen nicht in einem (einzigen) Experiment, sondern zeigen den Vergleich von Experimenten, bei denen der Gangunterschied (2*x0) zweier Wellenpakete (mit vorgegebener Breite und Wellenlänge) variiert wird. Beim Gangunterschied 0 ist die Interferenz voll sichtbar. Wird der Gangunterschied größer als die Paketbreite, treffen sich die Pakete nicht mehr und die Interferenz verschwindet. Wer hätte das gedacht? Man kann dieses Experiment übrigens auch mit Photonen ausführen - oder mit Bose-Einstein-Kondensaten!